***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 18, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4HE5P0A-AU A K 
.param
+vc0 = 2.106e-12		vc1 = 1.056e-9		vc2 = 2.000			vc3 = 2.365e-14		vc4 = 1.199e+1
+tc1 = 2.081e-2		tc2 = 1.511e-2		tc3 = 6.701e-3		tc4 = 4.021e-3
.func irpwr(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v**vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.111e-14	  	   n = 9.967e-1		  rs = 1.000e-3
+ibv = 10e-3		 nbv = 1.0			  bv = 6.7
+ikf = 1.243e-0
***** capacitance parameter *****
+cjo = 2.880e-9		   m = 3.604e-1		  vj = 7.770e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.082		 xti = 3
+trs1 = 1e-4		trs2 = -1e-6		tikf = 7.0e-3
+tbv1 = 4.318e-4		tbv2 = -2.446e-6	
.ends P4HE5P0A-AU
*$
